三元运算符版的IL
新语法"?."和三元运算符"?:"的结果是唯一的差别是IL_000a这一行。"?."的方式被编译为call，而"?:"的方式被编译为callvirt，不知为何"?:"中的persion.Name为何会被编译成支持多态方式调用的callvirt，在这种情况下貌似call效率会更高一些，但是终究"?."和"?:"编译的代码没有本质差异。
但是和if判断的相比简化了一些，我们分析下IL，看看有哪些差异（这里就忽略call和callvirt的区别了）：
if版的IL分析：
.method private hidebysig static void Main() cil managed
{
.entrypoint
.maxstack 2
.locals init ([0] class csharp6.Person person, //初始化局部变量person,把person放在索引为0的位置
[1] string name, //初始化局部变量name,把name放在索引为1的位置
[2] bool V_2) //初始化局部变量V_2,把V_2放在索引为2的位置
IL_0000: nop //空
IL_0001: ldnull //加载null
IL_0002: stloc.0 //把null放入索引为0的变量，也就是person对象。
IL_0003: ldnull //加载null
IL_0004: stloc.1 //把null放入索引为1的变量，也就是name对象。
IL_0005: ldloc.0 //加载索引为0的位置的变量，也就是person对象
IL_0006: ldnull //加载null
IL_0007: cgt.un //比较前两步加载的值。如果第一个值大于第二个值，则将整数值1推送到计算堆栈上；反之，将0推送到计算堆栈上。
IL_0009: stloc.2 //把比较结果放入索引为2的变量中，也就是V_2对象
IL_000a: ldloc.2 //加载索引为2的对象，也就是V_2对象
IL_000b: brfalse.s IL_0016 //如果上一步加载的对象为false、空引用或零，则跳转到IL_0016位置，也就是结束当前方法。
IL_000d: nop //空
IL_000e: ldloc.0 //加载索引为0的位置的变量，也就是person对象
IL_000f: callvirt instance string csharp6.Person::get_Name() //调用person对象的get_Name方法。
IL_0014: stloc.1 //把上一步的结果存入索引为1的变量中，也就是name对象。
IL_0015: nop //空
IL_0016: ret //返回
}
null条件运算符版的IL分析：
.method private hidebysig static void Main() cil managed
{
.entrypoint
.maxstack 1
.locals init ([0] class csharp6.Person person, //初始化局部变量person,把person放在索引为0的位置
[1] string name) //初始化局部变量name,把name放在索引为1的位置
IL_0000: nop //空
IL_0001: ldnull //加载null
IL_0002: stloc.0 //把null放入索引为0的变量，也就是person对象
IL_0003: ldloc.0 //加载索引为0的位置的变量，也就是person对象
IL_0004: brtrue.s IL_0009 //如果上一步加载的对象为true、非空引用或非零，则跳转到IL_0009位置
IL_0006: ldnull //加载null
IL_0007: br.s IL_000f //无条件的跳转到IL_000f处
IL_0009: ldloc.0 //加载索引为0的位置的变量，也就是person对象
IL_000a: call instance string csharp6.Person::get_Name() ////调用person对象的get_Name方法。
IL_000f: stloc.1 //把上一步的结果存入索引为1的变量中，也就是name对象。
IL_0010: ret //返回
}
